!* -*- Teco -*- *!

!* ZMOUSE: Helper stuff to make the mouse work in ZBabyl
	    when coming from a LispM.

 This library was created by and is maintained by KMP@MC.
 It is an extension to the Babyl mail reader, developed primarily
   by EAK@MC and ECC@MC.

 NOTE: In order for this library to win, you must have loaded
       EMACS;EMOUSE LISP (ITS) or <EMACS>EMOUSE.LISP (Twenex)
       into your LispM environment.

 Modification History:

04/14/85 2	KMP	Library installed as a standard Emacs library.
12/21/83 1	KMP	Library created.

*!

!~Filename~:! !Mouse support for ZBabyl from a LispM!
ZMOUSE

!& Setup ZMOUSE Library:! !S Set up our environment!

 1,m(m.m &_Get_Library_Pointer)EMOUSE"e
   m(m.m Load_Library)EMOUSE'

 :i*fo..QSurvey_Mode_Hook
 @:iH| H(
       1,(m.m &_ZMouse_Survey_Select)   m.l Mouse_L_Action
       1,(m.m &_ZMouse_Survey_Un/delete)m.l Mouse_M_Action
       )|
 qHm.V Survey_Mode_Hook


!& ZMouse Show Message:! !S Show the current message!

 0fo..Q Window_2_Size"e	    !* Assure two window mode		!
  @m(m.m ^R_Two_Windows)
  @m(m.m ^R_Other_Window)'
 @m(m.m^R_Survey_Menu_T)	    !* Display the message		!
 f


!& ZMouse Survey Select:! !S Select and display the item being pointed at!

 0,m(m.m &_Mouse_Move)	    !* Move the mouse			!
 0:m(m.m &_ZMouse_Show_Message)    !* Display this message		!


!& ZMouse Survey Un/delete:! !S Select msg and complement its deletedness!

 0,m(m.m &_Mouse_Move)	    !* Move the mouse			!
 @f_	l \f"n		    !* Pass whitespace and msg number	!
  1a-D"e U '"# D '[..0	    !* C: Name of command (D or U)	!
  @m(Afs^RInit)		    !* Fake the U or D			!
  :m(m.m &_ZMouse_Show_Message)'   !* Display this message		!
 0				    !* Return. No message, no changes	!